8.х Переменные В Печатной Форме

Привет.
Поскажите пожалуста.Как по аналогии примера Артикула таким же способ прикрепить напримерСпр.ХарактеристикиНоменклатуры(В Печатной Форме)?Артикул:
ДопКолонка = Константы.ДополнительнаяКолонкаПечатныхФормДокументов.Получить();
Если ДопКолонка = Перечисления.ДополнительнаяКолонкаПечатныхФормДокументов.Артикул Тогда
ТоварКод = "Артикул";
Иначе
ТоварКод = "Код";
КонецЕсли;
После добавляешь в Область параметр +""+ТоварКод.

понятно что создается переменная и передаешь туда параметры,что то не получается созать правельно эту перем.,киньте пожалуста пару примеров.Спасибо

Запутано все как-то, какие-то артикулы, переменные, параметры... Вы бы написали задачу, что конкретно сделать хотите, без всяких аналогий.

В печ.Форме есть Параметр Номеклатура,хочу в этом параметре добавить "ХарактеристикиНомеклатуры"(Спр.ХаракеристикиНоменклатуры)

Прямо в этот параметр или колонку дополнительную сделать?

да в этот параметр

я вот как добавлял Артикул
Область.Параметры.ПечМатериал =Обход.ТоварКод+" "+ Обход.ПечМатериал;

где.........
ДопКолонка = Константы.ДополнительнаяКолонкаПечатныхФормДокументов.Получить();
Если ДопКолонка = Перечисления.ДополнительнаяКолонкаПечатныхФормДокументов.Артикул Тогда
ТоварКод = "Артикул";
Иначе
ТоварКод = "Код";
КонецЕсли;

Ну, напишите тогда

Код:

Область.Параметры.Номенклатура =СокрЛП(Обход.Номенклатура.Наименование)+" "+СокрЛП(Обход.ХарактеристикаНоменклатуры.Наименование);

Это при условии, что в обходе у вас есть характеристики.

Я так с самого начало и делал,я не могу просто опредилить из какого регистра брать ХарактеристикиНоменклатуры их там аш 4 шт.
вот в запрос

Код:

ТекстЗапроса = 
"ВЫБРАТЬ РАЗРЕШЕННЫЕ
|	РегЗаказы.Материал КАК Материал,
|	РегЗаказы.ЕдИзм КАК ЕдИзм,
|	ПРЕДСТАВЛЕНИЕ(РегЗаказы.Материал) КАК ПечМатериал,
|	ПРЕДСТАВЛЕНИЕ(РегЗаказы.ЕдИзм) КАК ПечЕдИзм,
|	ПРЕДСТАВЛЕНИЕ(РегЗаказы.Материал.Артикул) КАК Артикул,
|	СУММА(РегЗаказы.КолПотребность) КАК КолПотребность,
|	СУММА(РегЗаказы.КолРезерв) КАК КолРезерв,
|	СУММА(РегЗаказы.КолРазмещено) КАК КолРазмещено,
|	СУММА(РегЗаказы.КолНЗП) КАК КолНЗП,
|	СУММА(РегЗаказы.КолПотребность - РегЗаказы.КолРезерв - РегЗаказы.КолРазмещено - РегЗаказы.КолНЗП) КАК Необеспечено
|ИЗ
|	(ВЫБРАТЬ
|		РегПотребности.Номенклатура КАК Материал,
|		РегПотребности.ЕдиницаИзмерения КАК ЕдИзм,
|		РегПотребности.КоличествоОстаток КАК КолПотребность,
|		0 КАК КолРезерв,
|		0 КАК КолРазмещено,
|		0 КАК КолНЗП
|	ИЗ
|		РегистрНакопления.ПотребностиЗаказовНаПроизводство.Остатки(&ДатаКон, ЗаказНаПроизводство = &Заказ) КАК РегПотребности
|	
|	ОБЪЕДИНИТЬ ВСЕ
|	
|	ВЫБРАТЬ
|		РегРезерв.Номенклатура,
|		РегРезерв.Номенклатура.ЕдиницаХраненияОстатков,
|		0,
|		РегРезерв.КоличествоОстаток,
|		0,
|		0
|	ИЗ
|		РегистрНакопления.ТоварыВРезервеНаСкладах.Остатки(&ДатаКон, ДокументРезерва = &Заказ) КАК РегРезерв
|	
|	ОБЪЕДИНИТЬ ВСЕ
|	
|	ВЫБРАТЬ
|		РегРазмещение.Номенклатура,
|		РегРазмещение.Номенклатура.ЕдиницаХраненияОстатков,
|		0,
|		0,
|		РегРазмещение.КоличествоОстаток,
|		0
|	ИЗ
|		РегистрНакопления.РазмещениеЗаказовПокупателей.Остатки(&ДатаКон, ЗаказПокупателя = &Заказ) КАК РегРазмещение
|"+?(ВидимостьНЗП, "	
|	ОБЪЕДИНИТЬ ВСЕ
|	
|	ВЫБРАТЬ
|		РегНЗП.Затрата,
|		РегНЗП.Затрата.ЕдиницаХраненияОстатков,
|		0,
|		0,
|		0,
|		РегНЗП.КоличествоОстаток
|	ИЗ
|		РегистрНакопления.МатериалыВПроизводстве.Остатки(&ДатаКон, Заказ = &Заказ) КАК РегНЗП","")+") КАК РегЗаказы
|
|СГРУППИРОВАТЬ ПО
|	РегЗаказы.Материал,
|	РегЗаказы.ЕдИзм
|
|УПОРЯДОЧИТЬ ПО
|	Материал.Наименование,
|	ЕдИзм.Наименование";

Здесь нужно из всех регистров характеристики тянуть и в группировку основного запроса их добавить

примерно,как то, понятно,а на примере сможешь показать?
у меня в последнем регистре нет ХарактеристикиНоменклатуры,есть ХарактеристикаЗатрат
| ИЗ
| РегистрНакопления.МатериалыВПроизводстве.Остатки(&ДатаКон, Заказ = &Заказ) КАК РегНЗП","")+") КАК РегЗаказы


с группировками по подробней

Код:

ТекстЗапроса = 
"ВЫБРАТЬ РАЗРЕШЕННЫЕ
|    РегЗаказы.Материал КАК Материал,
//Добавляем строку
|    РегЗаказы.Характеристика КАК Характеристика,
|    РегЗаказы.ЕдИзм КАК ЕдИзм,
|    ПРЕДСТАВЛЕНИЕ(РегЗаказы.Материал) КАК ПечМатериал,
|    ПРЕДСТАВЛЕНИЕ(РегЗаказы.ЕдИзм) КАК ПечЕдИзм,
|    ПРЕДСТАВЛЕНИЕ(РегЗаказы.Материал.Артикул) КАК Артикул,
|    СУММА(РегЗаказы.КолПотребность) КАК КолПотребность,
|    СУММА(РегЗаказы.КолРезерв) КАК КолРезерв,
|    СУММА(РегЗаказы.КолРазмещено) КАК КолРазмещено,
|    СУММА(РегЗаказы.КолНЗП) КАК КолНЗП,
|    СУММА(РегЗаказы.КолПотребность - РегЗаказы.КолРезерв - РегЗаказы.КолРазмещено - РегЗаказы.КолНЗП) КАК Необеспечено
|ИЗ
|    (ВЫБРАТЬ
|        РегПотребности.Номенклатура КАК Материал,
//Добавляем строку
|        РегПотребности.ХарактеристикаНоменклатуры КАК Характеристика,
|        РегПотребности.ЕдиницаИзмерения КАК ЕдИзм,
|        РегПотребности.КоличествоОстаток КАК КолПотребность,
|        0 КАК КолРезерв,
|        0 КАК КолРазмещено,
|        0 КАК КолНЗП
|    ИЗ
|        РегистрНакопления.ПотребностиЗаказовНаПроизводство.Остатки(&ДатаКон, ЗаказНаПроизводство = &Заказ) КАК РегПотребности
|    
|    ОБЪЕДИНИТЬ ВСЕ
|    
|    ВЫБРАТЬ
|        РегРезерв.Номенклатура,
//Добавляем строку
|        РегРезерв.ХарактеристикаНоменклатуры КАК Характеристика,
|        РегРезерв.Номенклатура.ЕдиницаХраненияОстатков,
|        0,
|        РегРезерв.КоличествоОстаток,
|        0,
|        0
|    ИЗ
|        РегистрНакопления.ТоварыВРезервеНаСкладах.Остатки(&ДатаКон, ДокументРезерва = &Заказ) КАК РегРезерв
|    
|    ОБЪЕДИНИТЬ ВСЕ
|    
|    ВЫБРАТЬ
|        РегРазмещение.Номенклатура,
//Добавляем строку
|        РегРазмещение.ХарактеристикаНоменклатуры КАК Характеристика,
|        РегРазмещение.Номенклатура.ЕдиницаХраненияОстатков,
|        0,
|        0,
|        РегРазмещение.КоличествоОстаток,
|        0
|    ИЗ
|        РегистрНакопления.РазмещениеЗаказовПокупателей.Остатки(&ДатаКон, ЗаказПокупателя = &Заказ) КАК РегРазмещение
|"+?(ВидимостьНЗП, "    
|    ОБЪЕДИНИТЬ ВСЕ
|    
|    ВЫБРАТЬ
|        РегНЗП.Затрата,
//Добавляем строку
|        РегНЗП.ХарактеристикаЗатраты КАК Характеристика,
|        РегНЗП.Затрата.ЕдиницаХраненияОстатков,
|        0,
|        0,
|        0,
|        РегНЗП.КоличествоОстаток
|    ИЗ
|        РегистрНакопления.МатериалыВПроизводстве.Остатки(&ДатаКон, Заказ = &Заказ) КАК РегНЗП","")+") КАК РегЗаказы
|
|СГРУППИРОВАТЬ ПО
|    РегЗаказы.Материал,
//Добавляем строку
|    РегЗаказы.Характеристика,
|    РегЗаказы.ЕдИзм
|
|УПОРЯДОЧИТЬ ПО
|    Материал.Наименование,
//Добавляем строку
|    Характеристика.Наименование,
|    ЕдИзм.Наименование";

вот это блин тебе спасибочки,выручил
Все работает